Logiciels Télécoms

Pour effectuer en survey un rapide calcul sur la hauteur d'antenne FH à installer de chaque coté d'une liaison, il y a un petit programme appelé "Profil de liaison" qui à partir de divers paramètres, détermine approximativement la hauteur en mètre de l'antenne à installer sur un support.

TRÈS PRATIQUE: Si vous possédez une calculatrice programmable, vous pouvez entrer les deux programmes ci-dessous pour effectuer les mêmes calculs.

Pour le profil de liaison, les données utiles au calcul sont:

- la fréquence (Ghz)
- la clirence (maximum = 1)
- le facteur de rotondité K ( généralement = 1.33 )
- la longueur du bond (km)
- la hauteur de végétation le long du parcourt (mètre)
- l'altitude du 1er site (mètre)
- l'altitude du 2ème site (mètre)
- la hauteur/sol de l'antenne coté 1er site(mètre)

ensuite il faut ajouter l'obstacle éventuel:

- l'altitude de l'obstacle(mètre)
- distance par rapport au 1er site (km)

Le programme est le suivant:

10 PRINT "Profil de liaison"
20 INPUT "Distance (km)=",D,"Frequence (GHz)=",F,"Vegetation (m)=",V,"Clirence=",C
25 INPUT "K=",K
30 INPUT "Alt 1er site(m)=",S
35 INPUT "Alt 2e site(m)=",N
40 INPUT "Alt de l'obstacle(m)=",O,"A quelle distance(km)=",E
41 IF E=0 THEN PRINT "Attention distance nulle"
50 L=C*17.3*(E*(D-E)/(F*D))^0.5
60 B=0.078*E*(D-E)/K
65 I=B+O+V+L 70 SETF2:PRINT "Hauteur Rayon direct=";I;"m"
90 SETF2:PRINT "Zone de Fresnel=";L;"m"
100 SETF2:PRINT "Rotodite=";B;"m"
110 INPUT "Hauteur 1er Ant(m)=",T
120 X=S+T+D*(I-S-T)/E-N
130 SETF1:PRINT "Hauteur 2e Ant=";X;"m"
140 INPUT "Avec Point milieu 1:Oui 0:Non=",U
141 IF U=0 THEN 30
142 IF U=1 THEN 145
145 INPUT "Alt du point milieu(m)=",Z
150 P=C*17.3*((D/2)^2/(F*D))^0.5
155 Q=0.078*((D/2)^2)/K
160 R=Q+Z+V+P
165 Y=S+T+D*(R-S-T)/(D/2)-N
170 SETF1:PRINT "Hauteur minimum 2e Ant=";Y;"m"
175 GOTO 30

Pour le Bilan de liaison, les données utiles sont:

- la fréquence (Ghz)
- la Puissance Emise
- le Seuil RX
- les Pertes
- les longueurs de guide d'onde
- les gains d'antennes
- la ou les distances du bond (km)

Le programme est le suivant:

10 CLEAR
20 PRINT "Bilan de liaison"
30 INPUT "Frequence(GHz)=",F
40 INPUT "Puissance Emise(dBm)=",E
50 INPUT "Seuil RX=",T
60 INPUT "Pertes Branchement=",P
70 INPUT "Pertes Coupleur-Attenuation=",Z
80 INPUT "Longueur Guide TX (m)=",L
90 INPUT "Perte Guide (dB/m)=",M
100 INPUT "Longueur Guide RX (m)=",S
110 INPUT "Perte Guide (dB/m)=",N
120 INPUT "Bond avec passif?(Oui=1,Non=2)=",I
130 ON I GOTO 500,140
140 INPUT "Distance (km)=",D
150 A=92.4+(20*(LOGF+LOGD))
160 INPUT "Gain Ant 1+2=",G
170 U=M*L
180 W=S*N
190 K=W+U+Z+P
200 Y=E+G
210 SETF2:PRINT "Gain total=";Y;"dB"
220 SETF2:PRINT "Aff Esp Libre=";A;"dB"
230 SETF2:PRINT "Pert TX+RX=";K;"dB"
240 J=K+A
250 O=Y-J
260 R=O-T
270 SETF2:PRINT "Pert totales="J;"dB"
280 SETF2:PRINT "Niveau Rx Calcule=";O;"dB"
290 SETF2:PRINT "Marge=";R;"dB"
300 K=1.4E-8
310 Q=1
330 C=3.5
340 I=K*Q*F*(D^C)*100*10^(-R/10)
350 SETE4:PRINT "Indisponibilte=";I;"%"
360 INPUT "Nouveau calcul (1PSF-2DRT)=",I
370 ON I GOTO 550,160
500 INPUT "Longueur du Bond (km)=",B
510 INPUT "Longueur du 2e Bond (km)=",H
520 C=92.4+(20(LOGF+LOGB))
530 I=92.4+(20(LOGF+LOGH))
535 D=B+H
540 A=C+I
550 INPUT "Gain Ant 1+2=",V
560 INPUT "Gain PSF",Q
570 G=V+Q
580 GOTO 170

reste plus qu'à les tester... Bonne Chance ! :-)